任何真正实用的工程开发都必然是多文件的。但是VBScript创建多文件工程要麻烦一点，它对多文件工程，代码复用的支持并不是太好。在C/C++工程里，我们已经习惯了通过一个include语句，并且声明一个函数原形的方式来使用其它模块中的函数，这样一个复杂的工程可以比较容易地分解成一些小的模块，以更容易理解和掌握。VBScript中情况有些不同。这与它的设计目标有关。最初VBScript是用在客户端脚本，以支持与客户端作简单的交互，如简单的输入检查等等。在浏览器里显然没有办法支持对另一个文件中的函数的调用，你不知道那个文件是否存在，何时存在。那么以本地脚本形式执行的VBScript又怎么样呢？想想看这条命令：cscript.exe yourscript.vbs。显然一个VBS运行在一个进程空间里（cscript进程），它也没有办法得到另一个文件中的函数。

认识到了VBScript的局限性，我们来看如何解决它。

第一种需要可能是需要在一个脚本运行的中间直接运行另外一个脚本。这可以通过下面的方法来完成：

Set WSHShell = CreateObject("WScript.Shell")
WSHShell.Run "wscript c:\Test.vbs param1", , True

注意到这里我们Test.vbs运行在另外一个进程空间（wscript进程）里，加上执行当前脚本的WSH，我们一共有两个进程。这是通过WSHShell.Run来做到的，这个方法的原型是：

object.Run(strCommand, [intWindowStyle], [bWaitOnReturn])

如果时序很重要，你可以在bWaitOnReturn这个参数中指定主脚本是否要等待被执行的脚本运行结束后才能继续。

另一点需要注意的地方是strCommand参数，这个参数是一个复合体，以空格区分各个域。如果需要将运行参数传递给被调用的脚本，应该在第二个空格后面输入。下面的例子显示了如何获取主脚本传递来的参数。对了，是通过WScript.Arguments来访问。WSCript还有其他一些有趣的属性，请记得读一下文档。

Set oArgs = WScript.Arguments
For i = 0 to oArgs.Count - 1
WScript.Echo oArgs(i)
Next

关于参数解析，这里给出一个Windows 2000 support tools中的一个脚本的例子。你可以复用这个函数，以解析任何以/ArgName:Value形式指定的参数。

' searches for and returns the value of a command line argument of the form
' /argName:value from the supplied array. erases the entry in the array so
' that only untouched entries remain.

function GetArgValue(argName, args())
dim a
dim v
dim argNameLength
dim x
dim argCount
dim fullArgName

fullArgName = "/" & argName & ":"
argCount = Ubound(args)

' Get the length of the argname we are looking for
argNameLength = Len(fullArgName)
GetArgValue = "" ' default to nothing

for x = 0 To argCount
if Len(args(x)) >= argNameLength then

a = Mid(args(x), 1, argNameLength)
if UCase(a) = UCase(fullArgName) then

' erase it so we can look for unknown args later
v = args(x)
args(x) = ""

if Len(v) > argNameLength then
GetArgValue = Mid(v, argNameLength + 1)
exit function
else
GetArgValue = ""
exit function
end if
end if
end if
next
end function

更多的时候，我们需要在脚本之间共享变量，以及相互调用函数。我们想要得到C/C++中那样的便利性：通过一个Include声明，就可以将另外一个模块中的函数和变量引入到当前的模块中。在VBScript中，可以通过ExecuteGlobal来实现:

Sub Include(sInstFile)
Dim oFSO, f, s
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set f = oFSO.OpenTextFile(sInstFile)
s = f.ReadAll
f.Close
ExecuteGlobal s
End Sub

这样，在脚本中加上这样一句调用：Include "mylib.vbs"，就可以使用mylib.vbs中声明的全局变量和函数了！注意这里的函数ExecuteGlobal有一个类似的函数Execute，这里如果使用Execute的话，就达不到我们想要的效果。因为通过Execute暴露的名字，其作用范围局限于Execute所处的级别，在这里，也就是在函数Include内部。这几乎肯定不是你想要的结果。

还有别的方法吗？是的。VBScript内在的支持COM方式。如果可以将你的脚本编译成一个COM组件，就当然可以在别的脚本中调用组件中的方法了。恰好，MS提供了工具Script Component Wizard来帮助我们将一些VBScript文件打包成一个组件，并提供注册方法。

现在我们来学一些新的方法。我的意思是，这些方法是仅为WSH支持的，你可能以前并没有遇见过。WSH支持一种叫*.wsf的文件，这个文件本身是XML格式的，通过该文件可以将你的VBScript脚本，以及其它类型的脚本，比如batch，perl等等组装在一起，交给WSH来执行。这方面文档还算详细，这里就不多介绍了。

这一节里，介绍了由单个脚本文件组装成一个较大的工程的四种方法，通过运用这些方法，你可以建立自己的常用函数库，在各个脚本之间共享变量和传递数据，等等。
在网上找到一段实现的代码，在这次的项目中起了大作用了。用vbs实现很多复杂的业务时，需要把一些公共的函数，class等写在一个公共的可复用的vbs文件里，像个库一样，其他的脚本都包含这个库的脚本。
复制代码 代码如下:
Sub Include(sInstFile)
Dim oFSO, f, s
Set oFSO = CreateObject("Scripting.FileSystemObject")
Set f = oFSO.OpenTextFile(sInstFile)
s = f.ReadAll
f.Close
ExecuteGlobal s
End Sub

使用的时候，这个把这个sub放在代码里，然后用 Include "comm.vbs" 这样来包含以下就可以了
12下一页阅读全文